Macro de Tatics para Dragon Raja utilizando o ACTool

Descrição: O programa ACTool foi criado na linguagem de programação Delphi 7, sua interface é simples e intuitiva como podemos ver na imagem anterior, sua principal funcionalidade é a de automatizar determinadas tarefas, por este motivo ele geralmente é utilizado para criarmos macros de jogos. Para quem não sabe o que é macro, podemos defini-lo de maneira simples como, criar uma seqüência de comandos ou configurações relacionadas a um determinado programa, que permitirá que o computador realize uma determinada tarefa repetidamente sem a necessidade de estarmos em frente ao computador.

Para os interessados, indico mais a parte a seguir do artigo para as pessoas que estão mais acostumadas com macros, scripts, programação ou assunto relacionados, iremos ver dois exemplos de macros para o jogo Dragon Raja. Aviso a quem nunca jogou, bots geralmente proibidos nos servidores oficiais, mas os macros são permitidos. Ambos os exemplos estão bem comentados e portanto serão bem simples de compreender para aqueles que já têm certa experiência no assunto.

A seguinte seqüência de comandos permite que o seu personagem ataque repetitivamente o alvo encontrado no mapa de treinamento e desativa o trade.

Constants

//Sinaliza oque deve ou nao ser executado no macro, 0 = NAO e 1 = SIM.
AtaqueNormal_ = 1

//Mantém o macro ativo por um número de execusoes indeterminado.
LoopInfinito = -1

//Número de vezes que o personagem atacará com ataque normal,
//antes de utilizar-se de magia de ataque.
N_Ataques = -1

//Coordenadas do alvo.
Coordenada_X_do_alvo = -1
Coordenada_Y_do_alvo = -1

End

Call TradeOff

//Garante que o número de vezes que o macro executará seje válido.
If $LoopInfinito <> -1 and $LoopInfinito < 1
FormatNumber LoopInfinito = -1
End

//Garante que o número de ataques nao será negativo ou igual a zero.
If $N_Ataques < 0
FormatNumber N_Ataques = 150
End

//Captura a coordenada do alvo.
If $Coordenada_X_do_alvo < 0 or $Coordenada_Y_do_alvo < 0
Delay 1 sec
Say Posicione o mouse sobre o alvo. (20 Sec)
Delay 20 sec
FormatNumber Coordenada_X_do_alvo = {MouseX}
FormatNumber Coordenada_Y_do_alvo = {MouseY}
Delay 1 sec
Keys {ESC}
End

//Ataque normal no alvo selecionado.
Procedure AtacarAlvo
If $AtaqueNormal_ = 1
MousePos $Coordenada_X_do_alvo, $Coordenada_Y_do_alvo
Loop $N_Ataques
LeftMouseDown
Delay 1 sec
LeftMouseUp
End
End
End

//Desativa o trade.
Procedure TradeOff
Delay 1 sec
Say {Keypad /}tradeoff
Keys {Return}
Delay 1 sec
Keys {ESC}
End

Delay 1 sec
Say Iniciando..
Keys {ESC}

While $LoopInfinito = -1
Call AtacarAlvo
End

A seguinte seqüência de comandos permite que o seu personagem ataque repetitivamente o alvo encontrado no mapa de treinamento e desative o trade, no entanto desta vez o seu personagem irá utilizar o alimento de sua potion box sozinho. Esta versão nunca foi testada, se possível testem e deixem um comentário sobre a sua experiência com esta versão.

Constants

//Mantém o macro ativo por um número de execusoes indeterminado.
LoopInfinito = -1

//Número de vezes que o macro executará o ciclo antes de recuperar a
//barra de fome.
N_Ciclos = 100

//Número de vezes que o personagem usará a magia de recuperar a
//barra de fome.
N_ReduzirFome = 1

//Número de vezes que o personagem atacará com ataque normal,
//antes de utilizar-se de magia de ataque, buffer ou outros.
N_Ataques = -1

//Coordenadas do alvo.
Coordenada_X_do_alvo = -1
Coordenada_Y_do_alvo = -1

//Coordenadas da Potion Box.
Coordenada_X_do_ptbox = -1
Coordenada_Y_do_ptbox = -1

End

Call TradeOff

//Garante que o número de vezes que o macro executará seje válido.
If $LoopInfinito <> -1 and $LoopInfinito < 1
FormatNumber LoopInfinito = -1
End

//Garante que o número de ataques nao será negativo ou igual a zero.
If $N_Ataques < 0
FormatNumber N_Ataques = 5400
End

//Captura a coordenada do alvo.
If $Coordenada_X_do_alvo < 0 or $Coordenada_Y_do_alvo < 0
Delay 1 sec
Say Posicione o mouse sobre o alvo. (20 Sec)
Delay 20 sec
FormatNumber Coordenada_X_do_alvo = {MouseX}
FormatNumber Coordenada_Y_do_alvo = {MouseY}
Delay 1 sec
Keys {ESC}
End

//Captura a coordenada da Potion Box.
If $Coordenada_X_do_ptbox < 0 or $Coordenada_Y_do_ptbox < 0
Delay 1 sec
Say Posicione o mouse sobre a Potion Box. (20 Sec)
Delay 20 sec
FormatNumber Coordenada_X_do_ptbox = {MouseX}
FormatNumber Coordenada_Y_do_ptbox = {MouseY}
Delay 1 sec
Keys {ESC}
End

//Ataque normal no alvo selecionado.
Procedure AtacarAlvo
Delay 3 sec
MousePos $Coordenada_X_do_alvo, $Coordenada_Y_do_alvo
Delay 3 sec
Loop $N_Ataques
Keys {SPACE}
LeftMouseDown
Delay 1 sec
LeftMouseUp
End
End

//Come o alimento que estiver dentro da Potion Box.
Procedure ReduzirFome
Delay 3 sec
MousePos $Coordenada_X_do_ptbox, $Coordenada_Y_do_ptbox
Delay 3 sec
Loop $N_ReduzirFome
Delay 1 sec
RightMouseDown
Delay 1 sec
RightMouseUp
End
End

//Desativa o trade.
Procedure TradeOff
Delay 1 sec
Say {Keypad /}tradeoff
Keys {Return}
Delay 1 sec
Keys {ESC}
End

Delay 1 sec
Say Iniciando..
Keys {ESC}

While $LoopInfinito = -1
Loop $N_Ciclos
Call ReduzirFome
Call AtacarAlvo
End
End

A página e o programa estão no idioma inglês, para baixar o programa utilize este link, para acessar a página utilize este link, a seguir uma imagem da página.